HSpice Tutorial 10 - Some example Circuits and Netlist Codes

Here are some Example Circuits and respective netlist codes for familiarizing with HSpice.

Example 2:

EE105 SPICE Tutorial Example 2 - Simple Diode Circuit
.model tut_diode d (is=1e-14 vj=0.6 rs=10)
vs vs gnd 5V
rs vs vd 5k
d1 vd gnd tut_diode
.op
.end

Example 3: ( Different analysis for same circuit above)

EE105 SPICE Tutorial Example 3 - Simple Diode Circuit
.model tut_diode d (is=1e-14 vj=0.6 rs=10)
vs vs gnd 5V
rs vs vd 5k
d1 vd gnd tut_diode
.dc vs 0V 5V 0.01V
.option post=2
.end

Example 4:

EE105 SPICE Tutorial Example 4 - Simple RC High-Pass Filter
vs vs gnd ac 1V
c1 vs vo 1nF
r1 vo gnd 1k
.ac dec 500 100 1G
.option post=2
.end

Example 5:

EE105 SPICE Tutorial Example 5 - Complicated Resistor Network
vs vs gnd 1V
r1 vs 1 1k
r2 1 2 500
r3 2 vo 800
r4 2 gnd 200
r5 1 4 1.5k
r6 4 vo 700
r7 vo 5 100
r8 5 gnd 900
.tf v(vo) vs
.end

 

Example 6(Pole Zero analysis for Exaample 4):

EE105 SPICE Tutorial Example 6 - Pole-zero analysis of a high-pass filter
vs vs gnd ac 1V
c1 vs vo 1nF
r1 vo gnd 1k
.pz v(vo) vs
.end

Example 7:

EE105 SPICE Tutorial Example 7 - Computing rise time
vs vs gnd PWL(0s 0V 5ms 0V 5.001ms 5V 10ms 5V)
r1 vs vo 1k
c1 vo gnd 1uF
.tran 0.01ms 10ms
.measure tran trise trig v(vo) val=0.5 rise=1 targ v(vo) val=4.5 rise=1
.end

Visit HSpice Tutorial Page(Click Here)